Batch Script to Auto Update Sysinternals Tools
While the Microsoft Sysinternals tools are incredibly powerful and useful, the one feature they lack is the ability to check for new versions. Currently, you have to periodically check the Sysinternals site and compare versions between your system and the most recent official release in order to stay up to date.
As a better solution, we have created a batch script which will automatically update the Sysinternals tools you have on your system. All you have to do is put the batch script file into the folder where your Sysinternals tools are located and the script does the rest, no configuration is needed.
Here is how it works:
- The current list of tools from Sysinternals is downloaded and compared to the files on your system.
- If a match is found, the current version from Sysinternals is copied to your system.
- If a tool is currently running, it is closed and then restarted once the script completes.
The Script
@ECHO OFF
TITLE Sysinternals Updater
ECHO Sysintenals Updater
ECHO Written by: Jason Faulkner
ECHO SysadminGeek.com
ECHO.
ECHO.
SETLOCAL ENABLEDELAYEDEXPANSION
SET SysInternalsTools="%Temp%\SysInternalsTools.tmp.txt"
SET CurrentTasks="%Temp%\CurrentTasks.tmp.txt"
SET StartWhenFinished="%Temp%\StartWhenFinished.tmp.txt"
ECHO Detected directory: %~dp0
%~d0
CD %~p0
ECHO.
ECHO.
ECHO Downloading current tool list...
SET LiveShare=\\live.sysinternals.com\tools
START /MIN %LiveShare%
DIR %LiveShare% /B > %SysInternalsTools%
TASKLIST > %CurrentTasks%
ECHO ;Terminated tools > %StartWhenFinished%
ECHO.
ECHO Updating installed SysInternals tools
FOR /F %%A IN ('DIR /B') DO (
FOR /F "usebackq" %%B IN (%SysInternalsTools%) DO (
IF /I [%%A]==[%%B] (
ECHO Updating %%A
FOR /F "usebackq" %%C IN (%CurrentTasks%) DO (
IF /I [%%A]==[%%C] (
ECHO %%C is currently running, killing process - queue restart
ECHO %%C >> %StartWhenFinished%
TASKKILL /IM %%A /T /F
)
)
XCOPY %LiveShare%\%%B %%A /Y
ECHO.
)
)
)
ECHO.
ECHO Resuming killed tasks
FOR /F "usebackq skip=1" %%A IN (%StartWhenFinished%) DO (
ECHO Starting %%A
START "Sysinternals Tool" "%%A"
)
IF EXIST %SysInternalsTools% DEL %SysInternalsTools%
IF EXIST %CurrentTasks% DEL %CurrentTasks%
IF EXIST %StartWhenFinished% DEL %StartWhenFinished%
ENDLOCAL
ECHO.
PAUSE
Links
This article was written on 07/27/10
Daily Email Updates
You can get our IT articles in your inbox each day for free. Just enter your name and email below:
I usually schedule this every month or so within the folder of all my SysInternals tools.
—–
wget.exe http://download.sysinternals.com/Files/SysinternalsSuite.zip
7za.exe x SysinternalsSuite.zip -y
del SysinternalsSuite.zip
—–
Just a small hint:
command L does not exist
But still, nice script, will let it run on schedule on our server. Thanks
@JJ
Oops! Fixed the post.
I just do:
robocopy \\live.sysinternals.com\Tools sysinternals /MIR
It won’t do the fancy stopping and starting running processes thing though
This is a great script. Love the start/stop stuff too!
filehippo will check these and provide you with download links
Here is my old script… http://getsysinternals.codeplex.com/
It is meant to be scheduled, it will download only updated utils and notify you about updated on over email. But I guess with the broadband simple xcopy/robocopy is better solution. But back in the days…
This will do work wget -r http://live.sysinternals.com/
Yeah I wrote one too a while back… turns out the console version of wget has this feature built in….
Have a look-see for anyone interested. The script is only a few lines but requires wget.exe and a date stamper so that the date is stamped onto the name of the file.
Check it out…. Let me know if anyone likes it…….
http://drop.io/SysDownUp
http://www.kls-soft.com/wscc/index.php
I use it as a portable version and on my thumbdrive/dropbox
I receive this message when I execute the sysinternals update batch file within my sysinternals folder:
windows cannot access \\live.sysinternals.com\tools
The error code is 80070043.
I have been searching daily for a solution since I read this article.
Nice, but using PowerShell would have been more state-of-the-art …
“I receive this message when I execute the sysinternals update batch file within my sysinternals folder:
windows cannot access \\live.sysinternals.com\tools
The error code is 80070043.
I have been searching daily for a solution since I read this article.”
Same issue here.
Anyone know the problem and solution?